|
|
|
| 图片批量生成网页 |
| 运行环境： Win9x/NT/2000/XP/2003 |
（载入中...） |
| 文件大小： 1 K |
| 软件类别： BAT源码 |
| 软件语言： 简体中文 |
| 软件属性： 热 |
| 授权方式： 免费版 |
| 添加时间： 2008-3-21 16:56:59 |
| 软件等级： ★★★ |
| 软件绿化： 佚名 |
| 相关链接： 源码演示地址 源码注册地址 |
| 下载次数： 日： 周： 月： 总： |
| 软件添加： 审核:lodge 录入:lodge |
警告：运行BAT源码是一种危险的动作，如果你不熟悉，请不要尝试！
@echo off
title “图片批量生成网页”安装程序·增强版 & mode con: cols=57 lines=20 & color 0A
echo ━━━━━━━━━━━━━━━━━━━━━━━━━━
echo “图片批量生成网页”安装程序·增强版
echo by 黔南逸士 2008-1-12
echo ──────────────────────────
echo 本程序可在文件夹右键菜单加入“图片生成网页”选项，
echo 执行该选项可以在该文件夹中生成一个网页，并把该文件夹下
echo 的图片一次性全部插入网页中居中显示。
echo 我喜欢批处理，我的QQ：418751518
echo 欢迎和我交流，大虾小鸟，来者不拒！
echo 我的人文博客http://cqh325.blog.163.com
echo ━━━━━━━━━━━━━━━━━━━━━━━━━━
echo.
echo [1].默认安装…………………程序默认设置
echo [2].向导模式安装…………可以自定义设置
echo [3].卸载…………………从系统中移除程序
echo.
echo 选择后按回车键执行，不作选择按回车键退出。
echo.
set /p setup= 请选择（1/2/3）：
set regpath=HKCR\Folder\shell
if "%setup%"=="3" goto uninstall
if "%setup%"=="2" goto userinstall
if "%setup%"=="1" goto defultinstall
goto :eof
:userinstall
cls
:loop1
set /p pictype=1.定义你想插入网页的图片类型，多种类型的用半角空格分开，输入格式形如*.jpg *.bmp，请输入：
if "%pictype%"=="" echo 没有输入，将按默认类型设置。 & set pictype=*.jpg *.bmp *.gif
if "%pictype:~0,2%" NEQ "*." cls & echo 请输入正确格式，不要忘了输入星号和圆点！ & goto loop1
:loop2
set /p right=2.定义你的文件夹的右键菜单文字，请输入：
if "%right%"=="" echo 没有输入，将按默认文字设置。 & set right=图片生成网页
:loop3
set /p open=3.生成网页后是否自动打开(默认打开)？（y/n）
if "%open%"=="" echo 没有选择，将按默认设置。 & set open=y
echo 正在安装，请稍候……
goto install
:defultinstall
set pictype=*.jpg *.gif *.bmp
set webpag=newhtm
set right=图片生成网页
set open=y
:install
::在windows文件夹下生成pic2htm.bat文件
>%windir%\pic2htm.bat echo @echo off
>>%windir%\pic2htm.bat echo ::获得当前文件夹名称
>>%windir%\pic2htm.bat echo set "foldername=%%cd%%"
>>%windir%\pic2htm.bat echo :loop
>>%windir%\pic2htm.bat echo set "foldername=%%foldername:*\=%%"
>>%windir%\pic2htm.bat echo set "cd_tmp=%%foldername:\=%%"
>>%windir%\pic2htm.bat echo if not "%%cd_tmp%%"=="%%foldername%%" goto loop
>>%windir%\pic2htm.bat echo ::生成网页代码
>>%windir%\pic2htm.bat echo dir %pictype% /b ^>nul 2^>nul ^&^& (
>>%windir%\pic2htm.bat echo echo ^^^<title^^^>%%foldername%%^^^</title^^^> ^>"%%foldername%%.htm"
>>%windir%\pic2htm.bat echo echo ^^^<p align=center^^^>^^^<b^^^>^^^<font color="#0000FF" size="6"^^^>%%foldername%%^^^</font^^^>^^^</b^^^>^^^</p^^^> ^>^>"%%foldername%%.htm"
>>%windir%\pic2htm.bat echo echo ^^^<p align=center^^^> ^>^>"%%foldername%%.htm"
>>%windir%\pic2htm.bat echo for /f "delims=" %%%%i in ('dir %pictype% /b') do echo ^^^<img border="0" src="%%%%i" width=800 ^^^>^^^<br^^^>%%%%i^^^<br^^^>^^^<br^^^> ^>^>"%%foldername%%.htm"
>>%windir%\pic2htm.bat echo echo ^^^</p^^^> ^>^>"%%foldername%%.htm"
if /i "%open:~0,1%" NEQ "n" (echo start "" "%%foldername%%.htm" >>%windir%\pic2htm.bat)
>>%windir%\pic2htm.bat echo goto end )
>>%windir%\pic2htm.bat echo start mshta vbscript:msgbox("该文件夹下没有%pictype%图片，如果你想把其他类型的图片插入网页，请重新用向导模式安装本程序！",16,"操作错误")(window.close)
>>%windir%\pic2htm.bat echo :end
>>%windir%\pic2htm.bat echo exit
::修改注册表实现右键功能
reg add "%regpath%\pic2htm" /ve /d %right%^(^&P^) /f >nul
reg add "%regpath%\pic2htm\command" /ve /d "cmd.exe /K CD %%1 & pic2htm.bat" /f >nul
mshta vbscript:msgbox("安装成功！你可以右键单击文件夹图标看到菜单了。",64,"操作提示")(window.close)
goto end
:uninstall
if exist %windir%\pic2htm.bat del /q %windir%\pic2htm.bat
reg delete "%regpath%\pic2htm" /f >nul 2>nul
mshta vbscript:msgbox("“图片批量生成网页”已经卸载成功！。",64,"操作提示")(window.close)
:end
|
@echo off
title “图片批量生成网页”安装程序·增强版 & mode con: cols=57 lines=20 & color 0A
echo ━━━━━━━━━━━━━━━━━━━━━━━━━━
echo “图片批量生成网页”安装程序·增强版
echo by 黔南逸士 2008-1-12
echo ──────────────────────────
echo 本程序可在文件夹右键菜单加入“图片生成网页”选项，
echo 执行该选项可以在该文件夹中生成一个网页，并把该文件夹下
echo 的图片一次性全部插入网页中居中显示。
echo 我喜欢批处理，我的QQ：418751518
echo 欢迎和我交流，大虾小鸟，来者不拒！
echo 我的人文博客http://cqh325.blog.163.com
echo ━━━━━━━━━━━━━━━━━━━━━━━━━━
echo.
echo [1].默认安装…………………程序默认设置
echo [2].向导模式安装…………可以自定义设置
echo [3].卸载…………………从系统中移除程序
echo.
echo 选择后按回车键执行，不作选择按回车键退出。
echo.
set /p setup= 请选择（1/2/3）：
set regpath=HKCR\Folder\shell
if "%setup%"=="3" goto uninstall
if "%setup%"=="2" goto userinstall
if "%setup%"=="1" goto defultinstall
goto :eof
:userinstall
cls
:loop1
set /p pictype=1.定义你想插入网页的图片类型，多种类型的用半角空格分开，输入格式形如*.jpg *.bmp，请输入：
if "%pictype%"=="" echo 没有输入，将按默认类型设置。 & set pictype=*.jpg *.bmp *.gif
if "%pictype:~0,2%" NEQ "*." cls & echo 请输入正确格式，不要忘了输入星号和圆点！ & goto loop1
:loop2
set /p right=2.定义你的文件夹的右键菜单文字，请输入：
if "%right%"=="" echo 没有输入，将按默认文字设置。 & set right=图片生成网页
:loop3
set /p open=3.生成网页后是否自动打开(默认打开)？（y/n）
if "%open%"=="" echo 没有选择，将按默认设置。 & set open=y
echo 正在安装，请稍候……
goto install
:defultinstall
set pictype=*.jpg *.gif *.bmp
set webpag=newhtm
set right=图片生成网页
set open=y
:install
::在windows文件夹下生成pic2htm.bat文件
>%windir%\pic2htm.bat echo @echo off
>>%windir%\pic2htm.bat echo ::获得当前文件夹名称
>>%windir%\pic2htm.bat echo set "foldername=%%cd%%"
>>%windir%\pic2htm.bat echo :loop
>>%windir%\pic2htm.bat echo set "foldername=%%foldername:*\=%%"
>>%windir%\pic2htm.bat echo set "cd_tmp=%%foldername:\=%%"
>>%windir%\pic2htm.bat echo if not "%%cd_tmp%%"=="%%foldername%%" goto loop
>>%windir%\pic2htm.bat echo ::生成网页代码
>>%windir%\pic2htm.bat echo dir %pictype% /b ^>nul 2^>nul ^&^& (
>>%windir%\pic2htm.bat echo echo ^^^<title^^^>%%foldername%%^^^</title^^^> ^>"%%foldername%%.htm"
>>%windir%\pic2htm.bat echo echo ^^^<p align=center^^^>^^^<b^^^>^^^<font color="#0000FF" size="6"^^^>%%foldername%%^^^</font^^^>^^^</b^^^>^^^</p^^^> ^>^>"%%foldername%%.htm"
>>%windir%\pic2htm.bat echo echo ^^^<p align=center^^^> ^>^>"%%foldername%%.htm"
>>%windir%\pic2htm.bat echo for /f "delims=" %%%%i in ('dir %pictype% /b') do echo ^^^<img border="0" src="%%%%i" width=800 ^^^>^^^<br^^^>%%%%i^^^<br^^^>^^^<br^^^> ^>^>"%%foldername%%.htm"
>>%windir%\pic2htm.bat echo echo ^^^</p^^^> ^>^>"%%foldername%%.htm"
if /i "%open:~0,1%" NEQ "n" (echo start "" "%%foldername%%.htm" >>%windir%\pic2htm.bat)
>>%windir%\pic2htm.bat echo goto end )
>>%windir%\pic2htm.bat echo start mshta vbscript:msgbox("该文件夹下没有%pictype%图片，如果你想把其他类型的图片插入网页，请重新用向导模式安装本程序！",16,"操作错误")(window.close)
>>%windir%\pic2htm.bat echo :end
>>%windir%\pic2htm.bat echo exit
::修改注册表实现右键功能
reg add "%regpath%\pic2htm" /ve /d %right%^(^&P^) /f >nul
reg add "%regpath%\pic2htm\command" /ve /d "cmd.exe /K CD %%1 & pic2htm.bat" /f >nul
mshta vbscript:msgbox("安装成功！你可以右键单击文件夹图标看到菜单了。",64,"操作提示")(window.close)
goto end
:uninstall
if exist %windir%\pic2htm.bat del /q %windir%\pic2htm.bat
reg delete "%regpath%\pic2htm" /f >nul 2>nul
mshta vbscript:msgbox("“图片批量生成网页”已经卸载成功！。",64,"操作提示")(window.close)
:end
|
* 为了达到最快的下载速度，推荐使用网际快车下载本站软件。
* 如果您发现该软件不能下载，请通知管理员或点击【此处报错】，谢谢！
* 未经本站明确许可，任何网站不得非法盗链及抄袭本站资源；如引用页面，请注明来自本站，谢谢您的支持！ |
|
|
| 网友评论：（评论内容只代表网友观点，与本站立场无关！） |
【发表评论】 |
|
|
